#-------------------------------------------------
#
# Project created by QtCreator 2020-11-18T10:59:17
#
#-------------------------------------------------

QT       += core gui opengl serialport network

CONFIG  += c++11

greaterThan(QT_MAJOR_VERSION, 4): QT += widgets printsupport

TARGET = GeneralThermalImageSystem
TEMPLATE = app

DESTDIR=$$PWD/../bin

# The following define makes your compiler emit warnings if you use
# any feature of Qt which has been marked as deprecated (the exact warnings
# depend on your compiler). Please consult the documentation of the
# deprecated API in order to know how to port your code away from it.
DEFINES += QT_DEPRECATED_WARNINGS

DEFINES += _XKEYCHECK_H     #pcie class error/warning disabled

INCLUDEPATH += $$PWD/../Common/ \
               $$PWD/../Common/include/ \
               $$PWD/./3rd/QCustomPlot \
               $$PWD/./3rd/JsonCpp \
               $$PWD/./3rd/JsonCpp/json \
               $$PWD/./UIs \
               $$PWD/./Protocal \

SOURCES += \
    main.cpp \
    mainwindow.cpp \
    RecordThread.cpp \
    FileOperator.cpp \
    FrameParams.cpp \
    TGAirthProcess.cpp \
    Serial/serialhelp.cpp \
    Serial/SerialMovement.cpp \
    Serial/SerialPortScan.cpp \
    UIs/LogIn/LoginDialog.cpp \
    UIs/LogIn/GdDataBaseOperate.cpp \
    UIs/AdvanceMode/SettingsPanel.cpp \
    UIs/AdvanceMode/SettingsControl.cpp \
    UIs/AdvanceMode/GetSystemCode.cpp \
    UIs/UserMode/UserControl.cpp \
    UIs/UserMode/UnCoolDevSettings.cpp \
    UIs/UIHelp/CustomSlider.cpp \
    UIs/UIHelp/frameless_helper.cpp \
    UIs/UIHelp/frmmessagebox.cpp \
    UIs/UIHelp/ConfigHelp.cpp \
    UIs/UIHelp/NoWheelSlider.cpp \
    UIs/UIHelp/LightLabel.cpp \
    UIs/UIHelp/CustomLineEdit.cpp \
    3rd/QCustomPlot/qcustomplot.cpp \
    3rd/QCustomPlot/qcustomplotcommon.cpp \
    3rd/JsonCpp/jsoncpp.cpp \

HEADERS += \
    mainwindow.h \    
    RecordThread.h \
    FrameParams.h \
    TGAirthProcess.h \
    FrameData.h \
    FileOperator.h \
    Protocal/Protocal_Cmds.h \
    Protocal/Protocal_StructInfoes.h \
    Serial/serialhelp.h \
    Serial/SerialMovement.h \    
    Serial/SerialPortScan.h \
    UIs/LogIn/LoginDialog.h \
    UIs/LogIn/GdDataBaseOperate.h \
    UIs/LogIn/SingleTon.h \
    UIs/AdvanceMode/SettingsPanel.h \
    UIs/AdvanceMode/SettingsControl.h \
    UIs/AdvanceMode/GetSystemCode.h \
    UIs/UserMode/UnCoolDevSettings.h \
    UIs/UserMode/UserControl.h \
    UIs/UIHelp/commonhelper.h \
    UIs/UIHelp/CustomSlider.h \
    UIs/UIHelp/frameless_helper.h \
    UIs/UIHelp/frmmessagebox.h \
    UIs/UIHelp/ConfigHelp.h \
    UIs/UIHelp/NoWheelSlider.h \
    UIs/UIHelp/LightLabel.h \
    UIs/UIHelp/CustomLineEdit.h \
    3rd/QCustomPlot/qcustomplot.h \
    3rd/QCustomPlot/qcustomplotcommon.h \
    3rd/JsonCpp/json/json-forwards.h \
    3rd/JsonCpp/json/json.h \
    Arith/Test.h \
    Arith/GetNETDrate.h \
    Arith/GetIndexofY16.h \
    Arith/GetIndexofY8.h \
    Arith/GetAvg.h \
    Arith/ImgProcessDll.h \

FORMS += \
    mainwindow.ui \
    FrameParams.ui \   
    UIs/LogIn/LoginDialog.ui \
    UIs/AdvanceMode/SettingsPanel.ui \
    UIs/AdvanceMode/SettingsControl.ui \
    UIs/AdvanceMode/GetSystemCode.ui \
    UIs/UserMode/UserControl.ui \
    UIs/UserMode/UnCoolDevSettings.ui \
    UIs/UIHelp/frmmessagebox.ui \

RESOURCES += \
    images.qrc

unix|win32: LIBS += -lcomsuppw

win32{
    contains(DEFINES,WIN64){
        LIBS += -L$$PWD/lib/x64 -lCpl64x64 -lImgProcessDll -lUsb3 -lBadpointsDll -lGetNumofBadpoint -lCH375DLL64
        LIBS += -L$$PWD/lib/x64 -lGetIndexofY8 -lGetIndexofY16 -lGetNETDrate -lTest -lGetAvg
    }else{
        LIBS += -L$$PWD/lib/x86 -lCpl64 -lImgProcessDll -lUsb3 -lBadpointsDll -lGetNumofBadpoint -lCH375DLL64
        LIBS += -L$$PWD/lib/x64 -lGetIndexofY8 -lGetIndexofY16 -lGetNETDrate -lTest -lGetAvg
    }
}

win32 {
    DEPLOY_TOOL = $${dirname(QMAKE_QMAKE)}/windeployqt.exe
    DEPLOY_TOOL = $$replace(DEPLOY_TOOL, /, \\)
    contains(CONFIG, debug, debug|release){
        TARGET = $$join(TARGET,d)
        DEPLOY_TARGET = $${DESTDIR}/$${TARGET}.exe
    }else{
        DEPLOY_TARGET = $${DESTDIR}/$${TARGET}.exe
    }

    DEPLOY_TARGET=$$replace(DEPLOY_TARGET, /, \\)
    msvc {
        QMAKE_POST_LINK+=$$escape_expand("\\n\\t") $${DEPLOY_TOOL} $${DEPLOY_TARGET} --force $$escape_expand(\\n)
    }else{
        QMAKE_POST_LINK+='$$escape_expand("\\n\\t") $${DEPLOY_TOOL} $${DEPLOY_TARGET} --force $$escape_expand("\\n\\t")'
    }
    message("alter link execute command:" $$QMAKE_POST_LINK)
}

#文件采用utf-8编码
msvc {
    QMAKE_CFLAGS += /utf-8
    QMAKE_CXXFLAGS += /utf-8
}

# SDI采集卡需加载
#LIBS += -lole32

# exe所带图标
RC_ICONS = skin/ico/Guide.ico

include($$PWD/../Common/Common.pri)